class Point
{
  int x;
  int y;
  
  Point(int x, int y)
  {
    this.x = x;
    this.y = y;
  }
  
  Point(Point p)
  {
    x = p.x;
    y = p.y;
  }
}

void affichePoint(Point p)
{
  println(p.x+","+p.y);
}


class Releve
{
  int temps;
  float temperature;
  
  Releve(int tps, float temp)
  {
    temps = tps;
    temperature = temp;
  }

  Releve(Releve r)
  {
    temps = r.temps;
    temperature = r.temperature;
  }
}

Releve lireReleve(String s)
{
  Releve r;
  String[] tt;
  int temps;
  float temperature;
  
  tt = split(s," - ");
 
 temps = int(tt[0]);
 temperature = float(tt[1]);
 
 r = new Releve(temps, temperature); //  r = new Releve(int(tt[0]), float(tt[1]));

 return r;
}

Releve[] lireLesReleves(String nomFichier)
{
  Releve[] rs;
  String[] lines = loadStrings(nomFichier);
  int nbR = lines.length;
  
  rs = new Releve[nbR];
  for (int i = 0; i<nbR; i++)
  {
    rs[i] = lireReleve(lines[i]);
  }
  
  return rs;
}

float calculEchelleX(Releve[] rs)
{
  int maxTemps = rs[0].temps;
    
  for (Releve r : rs) {
    if (r.temps > maxTemps)
      maxTemps = r.temps;
  }
  
  return 1.0*tailleX/maxTemps;
}

float calculEchelleY(Releve[] rs)
{
  float maxT = rs[0].temperature;
    
  for (Releve r : rs) {
    if (r.temperature > maxT)
      maxT = r.temperature;
  }
  
  return 1.0*tailleY/maxT;
}

Point[] conversionReleveEnPoint(Releve[] rs)
{
  Point[] ps;
  int nbR = rs.length;
  float fX, fY;
  fX = calculEchelleX(rs);
  fY = calculEchelleY(rs);
  
  ps = new Point[nbR];
  for (int i = 0; i<nbR; i++)
  {
    ps[i] = new Point((int) (rs[i].temps*fX), (int) (tailleY - rs[i].temperature*fY));
  }
  
  return ps;
}

int tailleX, tailleY;

void setup()
{
  tailleX = 1000;
  tailleY = 400;  
  size(1000,400);
  background(255);
  frameRate(24); 
  
  Releve[] rs = lireLesReleves("temperatures.txt");
  Point[] ps = conversionReleveEnPoint(rs);
  
  for(int i=1;i<ps.length; i++) {
    line(ps[i-1].x,ps[i-1].y,ps[i].x,ps[i].y);
  }
}